Introdução
Este documento descreve como manter o base de dados empacotado de PostgreSQL (DB) limpa para uma instalação mais longa do Gerenciamento de energia de Cisco (CEM).
Informações de Apoio
O CEM armazena os dados recolhidos dos ativos em um base de dados de PostgreSQL. O DB obtém instalado junto com o CEM. Depois que você usa o CEM por um período mais longo, muitos dados obtêm armazenados no DB que pôde já não ser precisado pelo sistema ou pelo usuário.
Ao longo do tempo, isto pôde fazer com que o DB cresça muito grande que o tem é impacto no uso e no desempenho do espaço de disco geralmente. Este documento ajuda a compreender como você pode manter o DB em um estado limpo executando alguns scripts do grupo.
Problema
O CEM, da versão 5 avante, não tem para fora-- do mecanismo da limpeza da caixa, assim que pôde ser bom limpa o DB manualmente numa base regular. As tarefas de lote do exemplo que você pode encontrar aqui podem ser executadas numa base regular com uma tarefa programada em Windows.
Solução
Limpe dados de hora em hora
O CEM agrega (de hora em hora, diário, mensal, anual) os dados recolhidos numa base regular. É possível suprimir de uns dados de fonte mais velhos (por exemplo de hora em hora), isso é mais velho do que um período para que este nível de detalhe é já não relevante ao usuário. Mais velhos os dados são, menos relevante torna-se para manter dados detalhados no DB.
Quando você suprime destes dados de hora em hora, é que é já não possível gerar relatórios com granularidade de hora em hora para o período que os dados estão suprimidos. Dependem da necessidade, isto não são geralmente uma edição para uns dados mais velhos.
Você pode usar este script para executar esta ação:
@echo off
REM +++++++++++++++ CONFIG ++++++++++++++++
REM set days to keep hourly data
set KEEPDAYS=365
REM set password for DB auth
set PGPASSWORD=zzzzzzzzz
REM set tenant id
set tenant=t_xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM set psql.exe location
set pgbin="C:\Program Files (x86)\Cisco Energy Management\pgsql\bin"
REM +++++++++++++ END CONFIG ++++++++++++++
REM list of metric suffixes
set suffixes=(power,carbon,devicestatus,power_cost,powerdemand,utilization)
REM get current date/time for logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set logtimestamp=%%#
REM calculate oldest date that should be kept in DB
for /f "delims=" %%# in ('powershell get-date -date "$(get-date).adddays(-%KEEPDAYS%)" -format "{yyyyMMdd}"') do @set dbdate=%%#
echo Starting hourly data cleanup on %logtimestamp% >%logtimestamp%.txt
REM remove tmp file if it exists already
if exist %TEMP%\cemscleantmp.txt del /f %TEMP%\cemscleantmp.txt
REM find and store tables that need to be deleted in tmp file
for %%s in %suffixes% do (
%pgbin%\psql.exe -q -t -A -w -U postgres -d cloud -c "SELECT table_name FROM information_schema.tables where table_name < 'd%dbdate%_%%s' AND table_name LIKE 'd2%%_%%s';">>%TEMP%\cemscleantmp.txt
)
REM drop that table
for /f "tokens=*" %%t in (%TEMP%\cemscleantmp.txt) do (
echo -- dropping table %tenant%.%%t>>%logtimestamp%.txt
%pgbin%\psql.exe -w -U postgres -d cloud -c "DROP TABLE IF EXISTS %tenant%.%%t CASCADE">>%logtimestamp%.txt 2>&1
)
REM clean tmp file
if exist %TEMP%\cemscleantmp.txt del /f %TEMP%\cemscleantmp.txt
REM end logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set endtimestamp=%%#
echo Finished hourly data cleanup on %endtimestamp% >>%logtimestamp%.txt
O primeiro parte do script precisa de ser costurado ao ambiente. Estes valores devem ser mudados:
- KEEPDAYS: número de dias que os dados de hora em hora devem ser mantidos (por exemplo: KEEPDAYS=365 mantém detalhes de hora em hora por um ano e suprime do detalhe de hora em hora mais velho do que um ano)
- PGPASSWORD: a senha postgres-USER para o base de dados
- inquilino: a inquilino-identificação usada para esta instalação (pode ser encontrado em EnergyWiseProcessor.log)
- pgbin: local de instalação dos binários de PostgreSQL
Limpe o jornal de Objectstore
O objectstore CEM contém todos os objetos relevantes para o CEM e seu estado mais atrasado. Para poder olhar a história e examinar o estado de todos os objetos ou mesmo reverter a tempo a um ponto precedente, o CEM mantém um jornal de todas as ações executadas nos objetos no objectstore. Esta informação é útil mas torna-se menos relevante ao longo do tempo. Similar como com o detalhe de hora em hora, é uma boa ideia limpar entradas velhas no jornal.
Você pode usar este script para executar esta ação:
@echo off
REM +++++++++++++++ CONFIG ++++++++++++++++
REM set days to keep journal data
set KEEPDAYS=365
REM set password for DB auth
set PGPASSWORD=xxxyyyzzz
REM set tenant id
set tenant=t_xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM set psql.exe location
set pgbin="C:\Program Files (x86)\Cisco Energy Management\pgsql\bin"
REM +++++++++++++ END CONFIG ++++++++++++++
REM get current date/time for logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set logtimestamp=%%#
REM calculate oldest date that should be kept in DB
for /f "delims=" %%# in ('powershell get-date -date "$(get-date).adddays(-%KEEPDAYS%)" -format "{yyyy-MM-dd}"') do @set dbdate=%%#
echo Starting jx_objectstore_journal cleanup script on %logtimestamp% >%logtimestamp%.txt
REM clean journal
%pgbin%\psql.exe -w -U postgres -d cloud -c "DELETE FROM %tenant%.jx_objectstore_journal where start <= '%dbdate%'" >>%logtimestamp%.txt 2>&1
REM end logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set endtimestamp=%%#
echo Finished jx_objectstore_journal cleanup script on %endtimestamp% >>%logtimestamp%.txt
O primeiro parte do script precisa de ser costurado ao ambiente. Estes valores devem ser mudados:
- KEEPDAYS: número de dias que os dados do jornal do objectstore devem ser mantidos (por exemplo: KEEPDAYS=365 mantém dados do jornal por um ano e suprime dos dados do jornal mais velhos do que um ano)
- PGPASSWORD: a senha postgres-USER para o base de dados
- inquilino: a inquilino-identificação usada para esta instalação (pode ser encontrado em EnergyWiseProcessor.log)
- pgbin: local de instalação dos binários de PostgreSQL
Se você executa estes scripts numa base regular, manterá o DB em um estado saudável e melhorará definidamente o desempenho (por exemplo: as velocidades do autovacuum, catálogo pedem…).
Feedback