Introduction
Ce document décrit comment garder la base de données empaquetée de PostgreSQL (DB) nettoient pour une installation plus longue de gestion énergétique de Cisco (CEM).
Le CEM enregistre les données collectées des ressources dans une base de données de PostgreSQL. Le DB obtient installé ainsi que le CEM. Après que vous utilisiez le CEM pendant une plus longue période, beaucoup de données obtiennent entreposé dans le DB qui pourrait plus n'être nécessaire par le système ou l'utilisateur.
Au fil du temps, ceci pourrait faire développer le DB très grand qui l'a est incidence sur l'utilisation et la représentation d'espace disque en général. Ce document aide à comprendre comment vous pouvez maintenir le DB dans un état propre en exécutant quelques scripts en lots.
Problème
Le CEM, de la version 5 en avant, n'a pas --le du mécanisme de nettoyage de case, ainsi il pourrait être bon nettoient le DB manuellement de façon régulière. Les traitements par lots d'exemple que vous pouvez trouver ici peuvent être exécutés de façon régulière avec une tâche programmée dans Windows.
Solution
Données horaires propres
Le CEM agrège (d'heure en heure, journal, mensuel, annuels) les données collectées de façon régulière. Il est possible de supprimer des données de base plus anciennes (par exemple d'heure en heure), cela est plus ancien qu'une période l'où ce niveau de précision n'est plus approprié à l'utilisateur. Plus les données sont anciennes, moins il devient pour maintenir des données détaillées dans le DB approprié.
Quand vous supprimez ces données horaires, est qu'il n'est plus possible de générer des états avec la finesse horaire pour la période que les données sont supprimées. Il dépend du besoin, ceci n'est habituellement pas une question pour des données plus anciennes.
Vous pouvez employer ce script pour exécuter cette action :
@echo off
REM +++++++++++++++ CONFIG ++++++++++++++++
REM set days to keep hourly data
set KEEPDAYS=365
REM set password for DB auth
set PGPASSWORD=zzzzzzzzz
REM set tenant id
set tenant=t_xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM set psql.exe location
set pgbin="C:\Program Files (x86)\Cisco Energy Management\pgsql\bin"
REM +++++++++++++ END CONFIG ++++++++++++++
REM list of metric suffixes
set suffixes=(power,carbon,devicestatus,power_cost,powerdemand,utilization)
REM get current date/time for logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set logtimestamp=%%#
REM calculate oldest date that should be kept in DB
for /f "delims=" %%# in ('powershell get-date -date "$(get-date).adddays(-%KEEPDAYS%)" -format "{yyyyMMdd}"') do @set dbdate=%%#
echo Starting hourly data cleanup on %logtimestamp% >%logtimestamp%.txt
REM remove tmp file if it exists already
if exist %TEMP%\cemscleantmp.txt del /f %TEMP%\cemscleantmp.txt
REM find and store tables that need to be deleted in tmp file
for %%s in %suffixes% do (
%pgbin%\psql.exe -q -t -A -w -U postgres -d cloud -c "SELECT table_name FROM information_schema.tables where table_name < 'd%dbdate%_%%s' AND table_name LIKE 'd2%%_%%s';">>%TEMP%\cemscleantmp.txt
)
REM drop that table
for /f "tokens=*" %%t in (%TEMP%\cemscleantmp.txt) do (
echo -- dropping table %tenant%.%%t>>%logtimestamp%.txt
%pgbin%\psql.exe -w -U postgres -d cloud -c "DROP TABLE IF EXISTS %tenant%.%%t CASCADE">>%logtimestamp%.txt 2>&1
)
REM clean tmp file
if exist %TEMP%\cemscleantmp.txt del /f %TEMP%\cemscleantmp.txt
REM end logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set endtimestamp=%%#
echo Finished hourly data cleanup on %endtimestamp% >>%logtimestamp%.txt
La première partie du script doit être conçue en fonction l'environnement. Ces valeurs devraient être changées :
- KEEPDAYS : nombre de jours que des données horaires devraient être gardé (par exemple : KEEPDAYS=365 garde les détails horaires pendant une année et supprime le détail horaire plus ancien qu'une année)
- PGPASSWORD : le mot de passe de postgres-utilisateur pour la base de données
- locataire : le locataire-id utilisé pour cette installation (peut être trouvé dans EnergyWiseProcessor.log)
- pgbin : emplacement d'installation des binaires de PostgreSQL
Journal propre d'Objectstore
L'objectstore de CEM contient tous les objets appropriés pour le CEM et leur dernier état. Pour pouvoir regarder l'historique et apurer le statut de tous les objets ou même retourner à un moment précédent, le CEM maintient un journal de toutes les actions exécutées sur les objets dans l'objectstore. Ces informations sont utiles mais deviennent moins appropriées au fil du temps. Semblable comme avec le détail horaire, c'est une bonne idée de nettoyer de vieilles entrées dans le journal.
Vous pouvez employer ce script pour exécuter cette action :
@echo off
REM +++++++++++++++ CONFIG ++++++++++++++++
REM set days to keep journal data
set KEEPDAYS=365
REM set password for DB auth
set PGPASSWORD=xxxyyyzzz
REM set tenant id
set tenant=t_xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM set psql.exe location
set pgbin="C:\Program Files (x86)\Cisco Energy Management\pgsql\bin"
REM +++++++++++++ END CONFIG ++++++++++++++
REM get current date/time for logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set logtimestamp=%%#
REM calculate oldest date that should be kept in DB
for /f "delims=" %%# in ('powershell get-date -date "$(get-date).adddays(-%KEEPDAYS%)" -format "{yyyy-MM-dd}"') do @set dbdate=%%#
echo Starting jx_objectstore_journal cleanup script on %logtimestamp% >%logtimestamp%.txt
REM clean journal
%pgbin%\psql.exe -w -U postgres -d cloud -c "DELETE FROM %tenant%.jx_objectstore_journal where start <= '%dbdate%'" >>%logtimestamp%.txt 2>&1
REM end logfile
for /f "delims=" %%# in ('powershell get-date -format "{yyyy-MM-dd_HH-mm}"') do @set endtimestamp=%%#
echo Finished jx_objectstore_journal cleanup script on %endtimestamp% >>%logtimestamp%.txt
La première partie du script doit être conçue en fonction l'environnement. Ces valeurs devraient être changées :
- KEEPDAYS : nombre de jours que des données de journal d'objectstore devraient être gardé (par exemple : KEEPDAYS=365 garde des données de journal pendant une année et les effacements inscrivent des données plus anciennes qu'une année)
- PGPASSWORD : le mot de passe de postgres-utilisateur pour la base de données
- locataire : le locataire-id utilisé pour cette installation (peut être trouvé dans EnergyWiseProcessor.log)
- pgbin : emplacement d'installation des binaires de PostgreSQL
Si vous exécutez ces scripts de façon régulière, il maintiendra le DB dans un état sain et améliorera certainement la représentation (par exemple : les vitesses d'autovacuum, catalogue demande…).
Commentaires